home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Gold Medal Software 3
/
Gold Medal Software - Volume 3 (Gold Medal) (1994).iso
/
utils2
/
sys117.arj
/
SYSTEM.BTM
next >
Wrap
Text File
|
1993-10-23
|
14KB
|
512 lines
@echo off
*break off
*cls
*del #@$().zb;#@$().ze;system.idx /z/q >&nul
*set > #@$().ze
*set esize=%_env
*set asize=%_alias
*alias > #@$().zb
*unalias *
set bg=%_bg
set fg=%_fg
set LAN=
text >system.idx
1) System Information
2) Memory Information
3) Disks Information
4) AUTOEXEC.BAT View
5) CONFIG.SYS View
6) SYSTEM.INI View
7) WIN.INI View
8) DBLSPACE.INI View
9) MEMMAKER.STS View
10) View a file
11) Aliases
12) Environment
13) About this program
14) Save Information to File
15) Quit
endtext
:main
cls %fg on %bg
drawbox 1 6 3 52 4 bright yellow on magenta fill magenta shadow
scrput 2 8 bright green on magenta System Information 1.17 by Schwartz Gabriel
set tempvar=%@select[system.idx,8,6,25,38]
set tempvar=%@substr[%tempvar,0,3]
iff "%tempvar"==" 1)" then goto system
elseiff "%tempvar"==" 2)" then goto memory
elseiff "%tempvar"==" 3)" then goto disk
elseiff "%tempvar"==" 4)" then goto autoexec
elseiff "%tempvar"==" 5)" then goto config
elseiff "%tempvar"==" 6)" then goto systemini
elseiff "%tempvar"==" 7)" then goto winini
elseiff "%tempvar"==" 8)" then goto dblspace
elseiff "%tempvar"==" 9)" then goto memmaker
elseiff "%tempvar"=="10)" then goto viewfile
elseiff "%tempvar"=="11)" then goto aliases
elseiff "%tempvar"=="12)" then goto envinroment
elseiff "%tempvar"=="13)" then goto programinfo
elseiff "%tempvar"=="14)" then goto saveinfo
endiff
goto quit
:system
DrawBox 1 2 22 74 1 bright magenta on %bg fill %bg shadow
scrput 3 7 bright yellow on %bg System Status:
gosub showtime
scrput 7 7 %fg on %bg Main Operating System: %_dos
scrput 8 7 %fg on %bg DOS Version: %_dosver
iff "%_4ver"=="" then scrput 9 7 %fg on %bg NDOS Version: %_nver
else scrput 9 7 %fg on %bg 4DOS Version: %_4ver
endiff
if %_dv == 1 scrput 10 7 %fg on %bg Multitasking: DESQview
if %_win == 1 scrput 10 7 %fg on %bg Multitasking: WINDOWS 2.x
if %_win == 2 scrput 10 7 %fg on %bg Multitasking: WINDOWS 3 Enhanced Mode
if %_win == 3 scrput 10 7 %fg on %bg Multitasking: WINDOWS 3 Real Mode
if %_win == 20 scrput 10 7 %fg on %bg Multitasking: OS/2 2.0 DOS Box
iff %_dv == 1 .OR. %_win == 1 .OR. %_win == 2 .OR. %_win == 3 .OR. %_win == 20 then set tempvar=11
else set tempvar=10
endiff
scrput %@eval[%tempvar] 7 %fg on %bg CPU class:
iff %_cpu == 200 then scrput %@eval[%tempvar] 18 %fg on %bg V20/V30
else scrput %@eval[%tempvar] 18 %fg on %bg 80%_cpu
endiff
scrput %@eval[%tempvar + 1] 7 %fg on %bg NPU class:
iff %_ndp ne 0 then scrput %@eval[%tempvar + 1] 18 %fg on %bg %_ndp Numeric Coprocessor detected
else scrput %@eval[%tempvar + 1] 18 %fg on %bg Numeric Coprocessor not detected
endiff
scrput %@eval[%tempvar + 2] 7 %fg on %bg Screen: %_COLUMNS*%_ROWS
scrput %@eval[%tempvar + 3] 7 %fg on %bg Video Adapter: %@upper[%_video]
scrput %@eval[%tempvar + 4] 7 %fg on %bg Monitor Type: %@upper[%_monitor]
iff %_ANSI ==1 then scrput %@eval[%tempvar + 5] 7 %fg on %bg ANSI Driver: Installed
else scrput %@eval[%tempvar + 5] 7 %fg on %bg ANSI Driver: Not installed
endiff
scrput %@eval[%tempvar + 6] 7 %fg on %bg Code Page: %_CODEPAGE
iff %_MOUSE == 1 then scrput %@eval[%tempvar + 7] 7 %fg on %bg Mouse Driver: Installed
else scrput %@eval[%tempvar + 7] 7 %fg on %bg Mouse Driver: Not installed
endiff
set tempvar=
:presskey
scrput 20 7 %fg on %bg Press any key to return to main menu...
screen 20 46
inkey /w1 %%tempvar
iff "%tempvar"=="" then gosub showtime^goto presskey
endiff
goto MAIN
:showtime
scrput 5 7 %fg on %bg Current Date: %_dow %_date
scrput 6 7 %fg on %bg Current Time: %_time
return
:memory
DrawBox 1 2 16 70 1 bright magenta on %bg fill %bg shadow
scrput 4 7 bright yellow on %bg Memory information
loadbtm off
scrput 6 7 %fg on %bg DOS Memory free: %@DOSMEM[b] bytes %@DOSMEM[K] Kilobytes %@INT[%@EVAL[%@DOSMEM[b]/640/1024*100]]%% free)
scrput 7 7 %fg on %bg Alias free: %asize bytes
scrput 8 7 %fg on %bg Environment free: %esize bytes
scrput 9 7 %fg on %bg Extended memory free: %@EXTENDED[b] bytes
scrput 10 7 %fg on %bg XMS Memory free: %@XMS[b] bytes
scrput 11 7 %fg on %bg EMS Memory free: %@EMS[b] bytes
set tempvar=%@search[mem.exe]
if "%tempvar" NE "" goto meminfo
loadbtm on
scrput 13 7 %fg on %bg Press any key to return to main menu...
screen 13 46
set tempvar=
inkey /w60 %%tempvar
goto main
:meminfo
set tempvar=Y
scrput 13 7 %fg on %bg Do you want to see memory usage? [Y/n]
screen 13 45
inkey %%tempvar
if "%tempvar"=="Y" .OR. "%tempvar"=="@28" goto memmap
goto memexit
:memmap
mem /c | list /s
:memexit
loadbtm on
goto main
:disk
DrawBox 1 2 19 75 1 bright magenta on %bg fill %bg shadow
scrput 3 7 bright yellow on %bg Drives information:
scrput 5 7 %fg on %bg BOOT Drive is: %_BOOT:
iff %@REMOVABLE[a:] == 1 then scrput 6 7 %fg on %bg Drive A: Removable
else scrput 6 7 %fg on %bg Drive A: Not Removable
endiff
iff %@REMOVABLE[b:] == 1 then scrput 7 7 %fg on %bg Drive B: Removable
else scrput 6 7 %fg on %bg Drive B: Not Removable
endiff
scrput 8 7 %fg on %bg Current Drive is: %_DISK:
scrput 9 7 %fg on %bg Disk Label is: %@LABEL[%_DISK:]
scrput 10 7 %fg on %bg Current Directory is: %_CWD
scrput 11 7 %fg on %bg Current Disk total: %@DISKTOTAL[%_DISK,b] bytes (%@DISKTOTAL[%_DISK,M] Megabytes)
scrput 12 7 %fg on %bg Current Disk used: %@DISKUSED[%_DISK,b] bytes (%@DISKUSED[%_DISK,M] Megabytes - %@INT[%@EVAL[%@DISKUSED[%_DISK,b]/%@DISKTOTAL[%_DISK,b]*100]]%% used)
scrput 13 7 %fg on %bg Current Disk free: %@DISKFREE[%_DISK,b] bytes (%@DISKFREE[%_DISK,M] Megabytes)
scrput 14 7 %fg on %bg Last Drive is: %_LASTDISK:
iff "%LAN"=="" then
for %drive in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) if %@remote[%drive:]==1 set LAN=%LAN% %drive:
if "%LAN"=="" set LAN= None
endiff
scrput 15 7 %fg on %bg LAN Drives:%LAN
scrput 17 7 %fg on %bg Press any key to return to main menu...
screen 17 46
set tempvar=
inkey /w60 %%tempvar
goto main
:autoexec
set tempvar=%@search[%_boot:\autoexec.bat]
iff "%tempvar"=="" then set tempvar=AUTOEXEC.BAT^gosub nofile^goto main
endiff
list %tempvar
goto main
:config
set tempvar=%@search[%_boot:\config.sys]
iff "%tempvar"=="" then set tempvar=CONFIG.SYS^gosub nofile^goto main
endiff
list %tempvar
goto main
:systemini
set tempvar=%@search[system.ini]
iff "%tempvar"=="" then set tempvar=SYSTEM.INI^gosub nofile^goto main
endiff
list %tempvar
goto main
:winini
set tempvar=%@search[win.ini]
iff "%tempvar"=="" then set tempvar=WIN.INI^gosub nofile^goto main
endiff
list %tempvar
goto main
:dblspace
set tempvar=%@search[dblspace.ini]
iff "%tempvar"=="" then set tempvar=DBLSPACE.INI^gosub nofile^goto main
endiff
list %tempvar
goto main
:memmaker
set tempvar=%@search[memmaker.sts]
iff "%tempvar"=="" then set tempvar=MEMMAKER.STS^gosub nofile^goto main
endiff
list %tempvar
goto main
:viewfile
drawbox 7 6 9 53 1 bright yellow on %bg fill %bg shadow
scrput 8 8 %fg on %bg View file :
screen 8 20
input %%tempvar
if "%tempvar"=="" goto main
if exist %tempvar goto showfile
gosub nofile
goto main
:showfile
list %tempvar
goto main
:aliases
list #@$().zb
goto main
:nofile
drawbox 7 6 13 53 1 bright yellow on red fill red shadow
scrput 9 8 bright yellow on red File %tempvar not found
scrput 11 8 bright yellow on red Press any key to return to Main Menu...
screen 11 47
pause > nul
return
:envinroment
list #@$().ze
goto main
:programinfo
cls bri yellow on %bg
text
SYSTEM ver 1.17 gives the current information:
A. Status:
. Current Date, Day of the week, time
. Running under DOS or OS/2
. DOS & 4DOS or NDOS version
. MultiTasking - Windows, OS/2, DESQview
. CPU & NPU class
. Screen Text Resolution, Video adapter, monitor, ANSI.SYS detecion
. Mouse Driver detection, CodePage number
B. Memory
. Free DOS Memroy
. Free ALIAS, Free Environment
. Free EXTENDED Memory, XMS & EMS
. Memory usage (Only if MEM.EXE from DOS is available)
C. DISKS
. BOOT Drive, Last drive
. Drives A:, B:
. Current Disk, Directory and Disk's LABEL
. Total Disk space, Used space, Free space
. LAN Drives
endtext
color bright green on %bg
pause Press any key to next page...
cls bright yellow on %bg
text
D. System files view
. AUTOEXEC.BAT
. CONFIG.SYS
. SYSTEM.INI
. WIN.INI
. DBLSPACE.INI
. MEMMAKER.STS
. Aliases
. View a file
. Envinroment settings
All this information is presented in organized menus.
All the information can be saved to a file!
just choose SAVE INFORMATION TO FILE on the main menu.
4DOS is as Registered Trademark of Rex C. Conn and J.P. Software Incorporated.
NDOS is as Registered Trademark of Symantec Corporation.
endtext
color bright green on %bg
pause
goto main
:saveinfo
drawbox 7 6 9 53 1 bright yellow on %bg fill %bg shadow
scrput 8 8 %fg on %bg Report to file :
screen 8 25
input %%tempvar
if "%tempvar"=="" goto main
iff exist %tempvar then
drawbox 14 7 16 43 1 bright yellow on red fill red shadow
scrput 15 9 bright yellow on red File %tempvar exists overwrite (Y/n) ?
screen 15 41
set yes=y
inkey %%yes
iff "%yes"=="Y" .OR. "%yes"=="@28" then del %tempvar /z/q
else goto main
endiff
endiff
drawbox 12 7 21 60 2 bright yellow on %bg fill %bg shadow
scrput 14 10 %fg on %bg Saving System information to file...
scrput 15 10 bright blink yellow on %bg Please wait...
text >%tempvar
SYSTEM.BTM System Information Report version 1.17
-------------------
System information:
-------------------
endtext
echo Current Date: %_dow %_date >>%tempvar
echo Current Time: %_time >>%tempvar
echo Main Operating System: %_dos >>%tempvar
echo DOS Version: %_dosver >>%tempvar
iff "%_4ver"=="" then echo NDOS Version: %_nver >>%tempvar
else echo 4DOS Version: %_4ver >>%tempvar
endiff
if %_dv == 1 echo Multitasking: DESQview >>%tempvar
if %_win == 1 echo Multitasking: WINDOWS 2.x >>%tempvar
if %_win == 2 echo Multitasking: WINDOWS 3 Enhanced Mode >>%tempvar
if %_win == 3 echo Multitasking: WINDOWS 3 Real Mode >>%tempvar
if %_win == 20 echo Multitasking: OS/2 2.0 DOS Box >>%tempvar
iff %_cpu == 200 then echo CPU class: V20/V30 >>%tempvar
else echo CPU class: 80%_cpu >>%tempvar
endiff
iff %_ndp ne 0 then echo NPU class: %_ndp Numeric Coprocessor detected >>%tempvar
else echo Numeric Coprocessor not detected >>%tempvar
endiff
echo Screen: %_COLUMNS*%_ROWS >>%tempvar
echo Video Adapter: %@upper[%_video] >>%tempvar
echo Monitor Type: %@upper[%_monitor] >>%tempvar
iff %_ANSI ==1 then echo ANSI Driver: Installed >>%tempvar
else echo ANSI Driver: Not installed >>%tempvar
endiff
echo Code Page: %_CODEPAGE >>%tempvar
iff %_MOUSE == 1 then echo Mouse Driver: Installed >>%tempvar
else echo Mouse Driver: Not installed >>%tempvar
endiff
text >>%tempvar
-------------------
Memory information:
-------------------
endtext
loadbtm off
echo DOS Memory free: %@DOSMEM[b] bytes (%@DOSMEM[K] Kilobytes %@INT[%@EVAL[%@DOSMEM[b]/640/1024*100]]%% free) >>%tempvar
echo Alias free: %asize bytes >>%tempvar
echo Environment free: %esize bytes >>%tempvar
echo Extended memory free: %@EXTENDED[b] bytes >>%tempvar
echo XMS Memory free: %@XMS[b] bytes >>%tempvar
echo EMS Memory free: %@EMS[b] bytes >>%tempvar
set drive=%@search[mem.exe]
if "%drive"=="" goto diskstempvar
mem /c >>%tempvar
:diskstempvar
loadbtm on
text >>%tempvar
------------------
Disks information:
------------------
endtext
echo BOOT Drive is: %_BOOT: >>%tempvar
iff %@REMOVABLE[a:] == 1 then echo Drive A: Removable >>%tempvar
else echo Drive A: Not Removable >>%tempvar
endiff
iff %@REMOVABLE[b:] == 1 then echo Drive B: Removable >>%tempvar
else echo Drive B: Not Removable >>%tempvar
endiff
echo Current Drive is: %_DISK: >>%tempvar
echo Disk Label is: %@LABEL[%_DISK:] >>%tempvar
echo Current Directory is: %_CWD >>%tempvar
echo Current Disk total: %@DISKTOTAL[%_DISK,b] bytes (%@DISKTOTAL[%_DISK,M] Megabytes) >>%tempvar
echo Current Disk used: %@DISKUSED[%_DISK,b] bytes (%@DISKUSED[%_DISK,M] Megabytes - %@INT[%@EVAL[%@DISKUSED[%_DISK,b]/%@DISKTOTAL[%_DISK,b]*100]]%% used) >>%tempvar
echo Current Disk free: %@DISKFREE[%_DISK,b] bytes (%@DISKFREE[%_DISK,M] Megabytes) >>%tempvar
echo Last Drive is: %_LASTDISK: >>%tempvar
iff "%LAN"=="" then
for %drive in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) if %@remote[%drive:]==1 set LAN=%LAN% %drive:
if "%LAN"=="" set LAN= None
endiff
echo LAN Drives:%LAN >>%tempvar
set drive=%@search[%_boot:\autoexec.bat]
if "%drive"=="" goto sysfile
text >>%tempvar
-------------
AUTOEXEC.BAT:
-------------
endtext
type %drive >>%tempvar
:sysfile
set drive=%@search[%_boot:\config.sys]
if "%drive"=="" goto systeminifile
text >>%tempvar
-----------
CONFIG.SYS:
-----------
endtext
type %drive >>%tempvar
:systeminifile
set drive=%@search[system.ini]
if "%drive"=="" goto wininifile
text >>%tempvar
-----------
SYSTEM.INI:
-----------
endtext
type %drive >>%tempvar
:wininifile
set drive=%@search[win.ini]
if "%drive"=="" goto dblspacefile
text >>%tempvar
--------
WIN.INI:
--------
endtext
type %drive >>%tempvar
:dblspacefile
set drive=%@search[dblspace.ini]
if "%drive"=="" goto memmakerfile
text >>%tempvar
-------------
DBLSPACE.INI:
-------------
endtext
type %drive >>%tempvar
:memmakerfile
set drive=%@search[memmaker.sts]
if "%drive"=="" goto aliasesfile
text >>%tempvar
-------------
MEMMAKER.STS:
-------------
endtext
type %drive >>%tempvar
:aliasesfile
text >>%tempvar
--------
Aliases:
--------
endtext
type #@$().zb >>%tempvar
:systemenvinroment
text >>%tempvar
------------
Envinroment:
------------
endtext
type #@$().ze >>%tempvar
text >>%tempvar
---------------------
SYSTEM: End Of Report
---------------------
endtext
describe %tempvar "SYSTEM 1.17 System Information file"
scrput 17 10 %fg on %bg System Information saved to file: %tempvar
scrput 19 10 %fg on %bg Press any key to return to main menu...
screen 19 49
pause > nul
goto main
:QUIT
cls %fg on %bg
unset *
set /r #@$().ze
alias /r #@$().zb
del #@$().zb;#@$().ze;system.idx /q
quit